تعریف نام‌های مستعار (Defining aliases)

یکی از رایج‌ترین کاربردهای توابع، تغییر اندک در رفتار یک دستور از پیش موجود است. برای نمونه، ممکن است بخواهید دستور ls را به گونه‌ای بازتعریف کنید که خروجی را رنگی نمایش دهد. سوییچ فعال‌سازی رنگ‌ها در سیستم‌های گنو --color=auto است. یک نام مستعار در پوشش دستور ls ممکن است به این شکل باشد:

function ls
    command ls --color=auto $argv
end

چند نکته مهم وجود دارد که باید در مورد نام‌های مستعار مد نظر قرار گیرند:

برای ساخت آسان تابعی با این ساختار، می‌توانید از دستور alias <> استفاده کنید. برخلاف سایر پوسته‌ها، این دستور صرفاً تابع می‌سازد - فیش مفهوم مستقلی به نام «alias» ندارد؛ ما صرفاً این واژه را برای چنین توابع پوششی ساده‌ای به کار می‌بریم. دستور alias <> بلافاصله یک تابع ایجاد می‌کند. استفاده از alias --save یا funcsave <> را در نظر داشته باشید تا تابع ایجادشده را در یک فایل بارگذاری خودکار ذخیره کنید، به جای اینکه هر بار نام مستعار را بازسازی نمایید.

به عنوان یک راهکار جایگزین، اختصارات abbreviations <#abbreviations> را امتحان کنید. این‌ها واژه‌هایی هستند که هنگام تایپ کردن بسط می‌یابند، نه اینکه توابع واقعی درون پوسته باشند.

بارگذاری خودکار توابع (Autoloading functions)

توابع را می‌توان در خط فرمان یا در یک فایل پیکربندی تعریف کرد، اما امکان بارگذاری خودکار آن‌ها نیز وجود دارد. این کار مزایایی به همراه دارد:

هنگامی که فیش نیاز به بارگذاری یک تابع دارد، دایرکتوری‌های موجود در متغیر فهرستی $fish_function_path را برای یافتن فایلی با نام متشکل از نام تابع به علاوه پسوند .fish جستجو کرده و نخستین فایلی را که می‌یابد بارگذاری می‌کند.

برای نمونه اگر تلاش کنید چیزی به نام banana را اجرا کنید، فیش تمامی دایرکتوری‌های موجود در $fish_function_path را برای یافتن فایلی به نام banana.fish پیمایش کرده و اولین مورد را بارگذاری می‌کند.

به طور پیش‌فرض $fish_function_path شامل موارد زیر است:

اگر مطمئن نیستید، توابع شما احتمالاً متعلق به دایرکتوری ~/.config/fish/functions هستند.

همان‌طور که توضیح دادیم، فایل‌های بارگذاری خودکار بر اساس نام لود می‌شوند؛ بنابراین با اینکه می‌توانید چندین تابع را درون یک فایل قرار دهید، آن فایل تنها زمانی به طور خودکار بارگذاری می‌شود که بخواهید تابعی هم‌نام با فایل را اجرا کنید.

بارگذاری خودکار برای گرداننده‌های رویداد (event handlers) نیز کار نخواهد کرد، زیرا فیش نمی‌تواند بداند که یک تابع قرار است هنگام وقوع یک رویداد اجرا شود، در حالی که هنوز آن تابع را بارگذاری نکرده است. برای اطلاعات بیشتر بخش گرداننده‌های رویداد را ببینید.

اگر فایلی با نام مناسب، تابع مورد نظر را تعریف نکند، فیش سایر فایل‌های بارگذاری خودکار را نخواهد خواند؛ بلکه به سراغ بررسی دستورات توکار و در نهایت دستورات خارجی می‌رود. این قابلیت امکان پوشش دادن (mask) تابعی را فراهم می‌کند که در ادامه مسیر $fish_function_path تعریف شده است؛ مثلاً زمانی که مدیر سیستم فایلی در /etc/fish/functions قرار داده که می‌خواهید آن را نادیده بگیرید.

اگر در حال توسعه برنامه‌ای دیگر هستید و می‌خواهید توابع فیش را برای آن نصب کنید، آن‌ها را در دایرکتوری توابع «تأمین‌کننده» (vendor) نصب نمایید. از آنجا که این مسیر در سیستم‌های مختلف متغیر است، می‌توانید با استفاده از pkgconfig و از طریق خروجی دستور pkg-config --variable functionsdir fish آن را پیدا کنید. سیستم نصب برنامه شما باید از مسیری سفارشی برای بازنویسی مسیر pkgconfig پشتیبانی کند تا توزیع‌کنندگان دیگر بتوانند به راحتی آن را تغییر دهند.

دستور if (The if statement)

دستور if <> در صورتی که شرط برقرار (true) باشد، یک بلوک از دستورات را اجرا می‌کند.

مشابه دیگر پوسته‌ها، اما برخلاف زبان‌های برنامه‌نویسی معمولی که ممکن است بشناسید، شرط در اینجا یک دستور است. فیش آن دستور را اجرا می‌کند و چنانچه وضعیت خروج آن درست (یعنی 0) باشد، بلوک if اجرا خواهد شد. برای مثال:

if test -e /etc/os-release
    cat /etc/os-release
end

این مثال از دستور test <> استفاده می‌کند تا بررسی کند آیا فایل /etc/os-release وجود دارد یا خیر. اگر وجود داشته باشد، دستور cat را اجرا می‌کند که محتوای آن را روی صفحه چاپ می‌نماید.

برخلاف پوسته‌های دیگر، دستور شرط بعد از نخستین کار (job) پایان می‌یابد و نیازی به واژه then نیست. ترکیب‌کننده‌هایی مانند and و or شرط را بسط می‌دهند.

نمونه‌ای پیچیده‌تر به همراه جایگزینی دستور:

if test "$(uname)" = Linux
    echo I like penguins
end

از آنجا که دستور test می‌تواند برای آزمایش‌های گوناگونی به کار رود، قرار دادن متغیرها و جایگزینی‌های دستور درون نقل‌قول اهمیت بالایی دارد. اگر $(uname) درون نقل‌قول قرار نمی‌گرفت و دستور uname هیچ متنی چاپ نمی‌کرد، عبارت test = Linux اجرا می‌شد که یک خطاست.

دستور if همچنین می‌تواند بندهای else if همراه با شرط‌های تکمیلی و یک بند else <> بپذیرد که در صورت نادرست بودن تمام شرط‌های قبلی اجرا می‌شود:

if test "$number" -gt 10
   echo Your number was greater than 10
else if test "$number" -gt 5
   echo Your number was greater than 5
else if test "$number" -gt 1
   echo Your number was greater than 1
else
   echo Your number was smaller or equal to 1
end

کلیدواژه not <> می‌تواند برای معکوس کردن وضعیت خروج به کار رود:

# Check if the file contains the string "fish" anywhere.
# This executes the `grep` command, which searches for a string,
# and if it finds it returns a status of 0.
# The `not` then turns 0 into 1 or anything else into 0.
# The `-q` switch stops it from printing any matches.
if not grep -q fish myanimals
    echo "You don't have fish!"
else
    echo "You have fish!"
end

سایر مواردی که معمولاً در شرط‌های if استفاده می‌شوند:

دستور switch (The switch statement)

دستور switch <> برای اجرای یکی از چند بلوک دستور بر اساس مقدار یک رشته به کار می‌رود. این دستور می‌تواند چندین بلوک case <> را بپذیرد که هنگام تطبیق رشته اجرا می‌شوند. این بلوک‌ها می‌توانند از الگوهای عام (wildcards) بهره ببرند. برای نمونه:

switch (uname)
case Linux
    echo Hi Tux!
case Darwin
    echo Hi Hexley!
case DragonFly '*BSD'
    echo Hi Beastie! # this also works for FreeBSD and NetBSD
case '*'
    echo Hi, stranger!
end

برخلاف برخی پوسته‌ها یا زبان‌های برنامه‌نویسی دیگر، پدیده سقوط (fallthrough) وجود ندارد - اولین بلوک case منطبق اجرا شده و سپس جریان کنترل از ساختار switch خارج می‌شود.

ترکیب‌کننده‌ها (and / or / && / ||) (Combiners)

برای بررسی‌های ساده می‌توانید از ترکیب‌کننده‌ها استفاده کنید. دستور and <> یا && در صورت موفقیت دستور اول، دستور دوم را اجرا می‌کند؛ در حالی که or <> یا || در صورت شکست دستور اول، دومی را اجرا می‌نمایند. برای نمونه:

# $XDG_CONFIG_HOME is a standard place to store configuration.
# If it's not set applications should use ~/.config.
set -q XDG_CONFIG_HOME; and set -l configdir $XDG_CONFIG_HOME
or set -l configdir ~/.config

توجه داشته باشید که ترکیب‌کننده‌ها به صورت تنبلی (lazy evaluation) اجرا می‌شوند - یعنی تنها بخشی که برای تعیین وضعیت نهایی لازم است اجرا می‌گردد.

مقایسه کنید:

if sleep 2; and false
    echo 'How did I get here? This should be impossible'
end

و:

if false; and sleep 2
    echo 'How did I get here? This should be impossible'
end

این دو دستور اساساً یک کار را انجام می‌دهند، اما حالت نخست ۲ ثانیه بیشتر طول می‌کشد زیرا دستور sleep همواره باید اجرا شود.

همچنین ممکن است حالتی داشته باشید که در آن توقف زودهنگام ضروری باشد:

if command -sq foo; and foo

اگر پردازش پس از پی بردن به اینکه دستور «foo» وجود ندارد ادامه می‌یافت، تلاش می‌کرد foo را اجرا کند و با خطای یافت نشدن دستور مواجه می‌شد!

ترکیب‌کننده‌ها گام به گام اجرا می‌شوند، بنابراین ساخت زنجیره‌های طولانی از آن‌ها پیشنهاد نمی‌شود چون ممکن است رفتاری ناخواسته ایجاد کنند. این مثال را در نظر بگیرید:

test -e /etc/my.config
or echo "OH NO WE NEED A CONFIG FILE"
and return 1

این زنجیره حتی اگر test هم موفق باشد، دستور return 1 را اجرا خواهد کرد! علت آن است که فیش دستور test -e /etc/my.config را اجرا کرده، متغیر $status را روی 0 می‌گذارد، سپس از echo عبور می‌کند و $status همچنان 0 باقی می‌ماند، و در نهایت return 1 را اجرا می‌کند چون $status هنوز 0 است.

بنابراین اگر شرط‌های پیچیده‌تری دارید یا می‌خواهید چند کار را پس از شکست یک دستور انجام دهید، استفاده از دستور if را مد نظر داشته باشید. در اینجا آن ساختار به این شکل خواهد بود:

if not test -e /etc/my.config
    echo "OH NO WE NEED A CONFIG FILE"
    return 1
end

کاراکترهای عام (Wildcards ("Globbing"))

هنگامی که یک پارامتر حاوی ستاره فاقد نقل‌قول * یا علامت سؤال ? باشد، فیش از آن به عنوان یک نویسه عام (wildcard) برای تطبیق فایل‌ها استفاده می‌کند.

تطبیق‌های نویسه‌های عام بدون حساسیت به بزرگی و کوچکی حروف مرتب می‌شوند. در هنگام مرتب‌سازی مواردی که حاوی عدد هستند، مرتب‌سازی به صورت طبیعی صورت می‌گیرد؛ به گونه‌ای که رشته‌های «1»، «5» و «12» مانند اعداد ۱، ۵ و ۱۲ مرتب می‌شوند.

فایل‌های مخفی (آن‌هایی که نامشان با یک نقطه آغاز می‌شود) در تطبیق عام در نظر گرفته نمی‌شوند مگر آنکه رشته الگوی عام، در آن موقعیت دارای نقطه باشد.

نویسه‌های عام هرگز به . (دایرکتوری جاری) یا .. (دایرکتوری والد) بسط نمی‌یابند.

مثال‌ها:

در اکثر دستورات، چنانچه بسط یک الگوی عام شکست بخورد، دستور اجرا نمی‌شود، متغیر $status روی مقداری غیر از صفر تنظیم شده و یک هشدار چاپ می‌گردد. این رفتار شبیه قابلیتی است که در bash با دستور shopt -s failglob فراهم می‌شود. استثنائاتی وجود دارد، از جمله دستورات set <> و path <>، بازنویسی متغیرها در overrides، دستور count <> و حلقه for <>. الگوهای عام این دستورات در صورت عدم تطبیق به صفر آرگومان بسط می‌یابند (بنابراین دستور اصلاً آن‌ها را نمی‌بیند)، شبیه رفتار shopt -s nullglob در بش.

مثال‌ها:

# List the .foo files, or warns if there aren't any.
ls *.foo
# List the .foo files, if any.
set foos *.foo
if count $foos >/dev/null
    ls $foos
end

برخلاف رفتار پیش‌فرض bash، فیش در صورت عدم یافتن تطبیق، کاراکتر عام را به همان شکل لفظی عبور نمی‌دهد؛ بنابراین برای دستوری مانند apt install که خود وظیفه تطبیق الگو را بر عهده دارد، باید از نقل‌قول استفاده کنید:

apt install "ncurses-*"

بسط متغیرها (Variable expansion)

یکی از مهم‌ترین بسط‌ها در فیش، «بسط متغیر» است. این عمل شامل جایگزینی علامت دلار ($) به دنبال نام متغیر، با مقدار آن متغیر می‌باشد.

یک مثال ساده:

echo $HOME

این دستور $HOME را با دایرکتوری خانگی کاربر جاری جایگزین کرده و آن را به دستور echo <> ارسال می‌کند تا چاپ شود.

برخی متغیرها مانند $HOME از پیش مقداردهی شده‌اند زیرا فیش آن‌ها را به صورت پیش‌فرض تنظیم می‌کند یا فرآیند والد هنگام راه‌اندازی فیش، آن‌ها را منتقل کرده است. شما می‌توانید متغیرهای اختصاصی خود را با دستور set <> مقداردهی کنید:

set my_directory /home/cooluser/mystuff
ls $my_directory
# shows the contents of /home/cooluser/mystuff

برای آگاهی بیشتر از نحوه مقداردهی متغیرها، به بخش متغیرهای پوسته و بخش‌های پس از آن مراجعه کنید.

گاهی یک متغیر مقداری ندارد چون تعریف نشده یا خالی است؛ در این صورت به هیچ چیز بسط نمی‌یابد:

echo $nonexistentvariable
# Prints no output.

برای جداسازی نام یک متغیر از متن، می‌توانید متغیر را درون نقل‌قول دوتایی یا آکولاد محصور کنید:

set WORD cat
echo The plural of $WORD is "$WORD"s
# Prints "The plural of cat is cats" because $WORD is set to "cat".
echo The plural of $WORD is {$WORD}s
# ditto

بدون نقل‌قول یا آکولاد، فیش تلاش می‌کند متغیری به نام $WORDs را بسط دهد که ممکن است وجود نداشته باشد.

نحو دوم یعنی {$WORD} حالت خاصی از بسط آکولاد است.

اگر متغیر $WORD در اینجا تعریف نشده باشد یا یک فهرست خالی باشد، حرف «s» چاپ نمی‌شود. با این حال اگر $WORD رشته خالی باشد (مانند پس از اجرای set WORD "")، حرف «s» چاپ خواهد شد.

برای کسب اطلاعات بیشتر درباره متغیرهای پوسته، بخش متغیرهای پوسته را مطالعه فرمایید.

نقل‌قول کردن متغیرها (Quoting variables)

بسط متغیرها در رشته‌های داخل نقل‌قول دوتایی نیز صورت می‌گیرد. درون نقل‌قول دوتایی ("این‌ها")، متغیرها همواره دقیقاً به یک آرگومان بسط می‌یابند. اگر خالی یا تعریف‌نشده باشند، نتیجه یک رشته خالی خواهد بود. اگر یک عنصر داشته باشند، به همان یک عنصر بسط پیدا می‌کنند. چنانچه بیش از یک عنصر داشته باشند، عناصر با فاصله (space) به هم متصل می‌شوند مگر اینکه متغیر یک متغیر مسیر (path variable) باشد که در آن صورت به جای فاصله از دونقطه (:) استفاده می‌گردد [3].

متغیرهای فیش همگی فهرست هستند و هنگام مقداردهی به عناصر تفکیک می‌شوند - این بدان معناست که تصمیم‌گیری در مورد استفاده یا عدم استفاده از نقل‌قول همراه با دستور set <> بسیار مهم است:

set foo 1 2 3 # a variable with three elements
rm $foo # runs the equivalent of `rm 1 2 3` - trying to delete three files: 1, 2 and 3.
rm "$foo" # runs `rm '1 2 3'` - trying to delete one file called '1 2 3'
set foo # an empty variable
rm $foo # runs `rm` without arguments
rm "$foo" # runs the equivalent of `rm ''`
set foo "1 2 3"
rm $foo # runs the equivalent of `rm '1 2 3'` - trying to delete one file
rm "$foo" # same thing

این رفتار برخلاف سایر پوسته‌ها است که عمل موسوم به «تفکیک کلمات» (Word Splitting) را انجام می‌دهند؛ یعنی متغیر را زمانی که در یک بسط استفاده می‌شود تفکیک می‌کنند. برای مثال در bash:

foo="1 2 3"
rm $foo # runs the equivalent of `rm 1 2 3`
rm "$foo" # runs the equivalent of `rm '1 2 3'`

این امر علت بروز خطاهای بسیار رایج در مواجهه با نام فایل‌های دارای فاصله در اسکریپت‌های بش است.

در فیش، متغیرهای فاقد نقل‌قول به تعداد عنصرهایی که دارند به آرگومان بسط می‌یابند. این یعنی یک فهرست خالی به هیچ چیز بسط نمی‌یابد، متغیری با یک عنصر به همان یک عنصر بسط پیدا می‌کند و متغیری با چند عنصر به هر یک از آن عناصر به صورت جداگانه بسط خواهد یافت.

اگر متغیری به هیچ چیز بسط یابد، هر رشته دیگری که به آن چسبیده باشد را نیز خنثی می‌کند. برای اطلاعات بیشتر بخش ترکیب فهرست‌ها را ببینید.

در بیشتر مواقع، نقل‌قول نکردن متغیر کار درستی است. استثنا زمانی است که نیاز دارید اطمینان یابید متغیر حتی در صورت خالی بودن یا داشتن چند عنصر، دقیقاً به عنوان یک عنصر منتقل شود. این وضعیت اغلب در دستور test <> رخ می‌دهد:

set -l foo one two three
test -n $foo
# prints an error that it got too many arguments, because it was executed like
test -n one two three
test -n "$foo"
# works, because it was executed like
test -n "one two three"

[3]

برخلاف bash یا zsh که با نخستین نویسه متغیر $IFS (که معمولاً فاصله است) پیوند می‌دهند.

ارجاع‌زدایی متغیرها (Dereferencing variables)

علامت $ می‌تواند به صورت چندباره نیز به کار رود، مانند نوعی عملگر «ارجاع‌زدایی» (مشابه * در C یا C++)؛ همان‌طور که در کد زیر مشاهده می‌شود:

set foo a b c
set a 10; set b 20; set c 30
for i in (seq (count $$foo))
    echo $$foo[$i]
end
# Output is:
# 10
# 20
# 30

عبارت $$foo[$i] یعنی «مقدار متغیری که نام آن توسط $foo[$i] مشخص شده است».

این شیوه همچنین می‌تواند برای ارسال نام یک متغیر به یک تابع به کار رود:

function print_var
    for arg in $argv
        echo Variable $arg is $$arg
    end
end
set -g foo 1 2 3
set -g bar a b c
print_var foo bar
# prints "Variable foo is 1 2 3" and "Variable bar is a b c"

البته متغیر باید از درون تابع قابل دسترسی باشد، بنابراین لازم است سراسری، جهانی (universal) یا صادرشده (exported) باشد. همچنین نباید با نام متغیری که درون تابع استفاده شده تداخل داشته باشد. اگر در آنجا $foo را متغیر محلی ساخته بودیم یا نام آن را «arg» گذاشته بودیم، کار نمی‌کرد.

هنگام استفاده از این قابلیت به همراه برش‌ها (slices)، برش‌ها از داخل به بیرون اعمال می‌شوند. عبارت $$foo[5] عنصر پنجم متغیر $foo را به عنوان نام متغیر استفاده می‌کند، به جای اینکه عنصر پنجم تمام متغیرهایی را بدهد که $foo به آن‌ها ارجاع دارد. برای حالت دوم، باید به صورت $$foo[1..-1][5] نوشته شود (تمامی عناصر $foo را بگیر، آن‌ها را به عنوان نام متغیرها به کار ببر، سپس عنصر پنجم آن‌ها را بده).

چند مثال دیگر:

set listone 1 2 3
set listtwo 4 5 6
set var listone listtwo
echo $$var
# Output is 1 2 3 4 5 6
echo $$var[1]
# Output is 1 2 3
echo $$var[2][3]
# $var[2] is listtwo, third element of that is 6, output is 6
echo $$var[..][2]
# The second element of every variable, so output is 2 5

متغیرها به عنوان دستور (Variables as command)

همانند دیگر پوسته‌ها، می‌توانید مقدار یک متغیر را به عنوان یک دستور اجرا کنید.

> set -g EDITOR emacs
> $EDITOR foo # opens emacs, possibly the GUI version

اگر بخواهید به دستور درون متغیر یک آرگومان بدهید، باید آن آرگومان یک عنصر مجزا در فهرست باشد:

> set EDITOR emacs -nw
> $EDITOR foo # opens emacs in the terminal even if the GUI is installed
> set EDITOR "emacs -nw"
> $EDITOR foo # tries to find a command called "emacs -nw"

همچنین مانند سایر پوسته‌ها، این قابلیت تنها برای دستورات، دستورات توکار و توابع کارایی دارد - برای کلیدواژه‌ها کار نخواهد کرد زیرا کلیدواژه‌ها اهمیت نحوی دارند.

برای نمونه، عبارت set if $if به شما امکان ساخت بلوک if را نمی‌دهد، و set cmd command اجازه استفاده به عنوان آذین‌گر command <> را نخواهد داد، بلکه تنها کاربردهایی مانند $cmd -q foo مجاز است.

جایگزینی دستور (Command substitution)

یک جایگزینی دستور بسطی است که از خروجی یک دستور به عنوان آرگومان‌های دستور دیگر استفاده می‌کند. برای مثال:

echo $(pwd)

این عبارت دستور pwd <> را اجرا کرده، خروجی آن را گرفته (به طور دقیق‌تر آنچه به جریان خروجی استاندارد «stdout» نوشته است) و آن را به عنوان آرگومان به دستور echo <> می‌دهد. بنابراین دستور درونی (pwd) ابتدا اجرا شده و باید پیش از شروع به کار دستور بیرونی، کار خود را به پایان برساند.

اگر دستور درونی چندین خط چاپ کند، فیش هر خط جداگانه را به عنوان یک آرگومان مستقل به دستور بیرونی تحویل می‌دهد. برخلاف دیگر پوسته‌ها، از مقدار متغیر $IFS استفاده نمی‌شود [4]؛ فیش بر اساس خطوط جدید (newline) تفکیک را انجام می‌دهد.

جایگزینی‌های دستور را می‌توان درون نقل‌قول دوتایی نیز قرار داد:

echo "$(pwd)"

هنگام استفاده از نقل‌قول دوتایی، خروجی دستور بر اساس خطوط تفکیک نمی‌شود، اما خطوط خالی انتهایی همچنان حذف می‌گردند.

اگر خروجی به عنوان گام پایانی به دستورات string split یا string split0 <> پایپ شود، آن تفکیک‌ها به همان صورتی که ظاهر می‌شوند به کار می‌روند، به جای آنکه بر اساس خطوط تفکیک شوند.

فیش همچنین نوشتن جایگزینی دستور بدون علامت دلار را ممکن می‌سازد، مانند echo (pwd). این شیوه درون نقل‌قول دوتایی بسط نمی‌یابد (echo "(pwd)" عبارت (pwd) را چاپ خواهد کرد).

وضعیت خروج آخرین جایگزینی دستور اجراشده در متغیر status در دسترس است، البته در صورتی که این جایگزینی در بستر یک دستور set <> رخ دهد (بنابراین عبارت if set -l (something) بررسی می‌کند که آیا دستور something وضعیت درست برگردانده است یا خیر).

برای استفاده تنها از برخی خطوط خروجی، به بخش برش‌ها (slices) مراجعه کنید.

مثال‌ها:

# Outputs 'image.png'.
echo (basename image.jpg .jpg).png
# Convert all JPEG files in the current directory to the
# PNG format using the 'convert' program.
for i in *.jpg; convert $i (basename $i .jpg).png; end
# Set the ``data`` variable to the contents of 'data.txt'
# without splitting it into a list.
set data "$(cat data.txt)"
# Set ``$data`` to the contents of data, splitting on NUL-bytes.
set data (cat data | string split0)

گاهی می‌خواهید خروجی یک دستور را به دستور دیگری ارسال کنید که تنها فایل می‌پذیرد. اگر خروجی تنها یک فایل است، معمولاً می‌توانید آن را از طریق پایپ ارسال کنید، مانند:

grep fish myanimallist1 | wc -l

اما اگر به چندین مورد نیاز دارید یا دستور از ورودی استاندارد نمی‌خواند، «جایگزینی فرآیند» (process substitution) کارآمد خواهد بود. سایر پوسته‌ها این کار را با نحو foo <(bar) <(baz) انجام می‌دهند، و فیش از دستور psub <> استفاده می‌کند:

# Compare only the lines containing "fish" in two files:
diff -u (grep fish myanimallist1 | psub) (grep fish myanimallist2 | psub)

این دستور یک فایل موقت می‌سازد، خروجی دستور را در آن فایل ذخیره کرده و نام فایل را چاپ می‌کند تا به دستور بیرونی داده شود.

پوسته فیش محدودیتی پیش‌فرض به میزان ۱ گیبی‌بایت (1 GiB) برای داده‌هایی که در جایگزینی دستور می‌خواند در نظر گرفته است. اگر این حد فراتر رود، کل دستور (تمام آن، نه فقط جایگزینی دستور - یعنی دستور بیرونی اصلاً اجرا نخواهد شد) شکست خورده و $status روی مقدار 122 تنظیم می‌شود. این امر به این دلیل است که جایگزینی دستور نتواند موجب اتمام حافظه سیستم شود، زیرا سیستم‌عامل شما معمولاً محدودیت بسیار پایین‌تری دارد و خواندن بیش از آن بی‌فایده و زیان‌بار خواهد بود. این محدودیت را می‌توان با متغیر fish_read_limit تغییر داد (مقدار 0 به معنای نبود محدودیت است). این محدودیت همچنین بر دستور read <> اثر می‌گذارد.

[4]

یک استثنا: خالی قرار دادن متغیر $IFS تفکیک خطوط را غیرفعال می‌کند. این شیوه منسوخ شده و بهتر است از string split <> استفاده کنید.

بسط آکولاد (Brace expansion)

آکولادها می‌توانند برای نوشتن فهرست‌های جداشده با کاما به کار روند. آن‌ها به گونه‌ای بسط داده می‌شوند که هر عنصر به یک پارامتر جدید تبدیل شده و رشته‌های پیرامونی به آن متصل می‌گردند. این قابلیت برای صرفه‌جویی در تایپ و نیز جداسازی نام متغیر از متن مجاور بسیار مفید است.

مثال‌ها:

> echo input.{c,h,txt}
input.c input.h input.txt
# Move all files with the suffix '.c' or '.h' to the subdirectory src.
> mv *.{c,h} src/
# Make a copy of `file` at `file.bak`.
> cp file{,.bak}
> set -l dogs hot cool cute "good "
> echo {$dogs}dog
hotdog cooldog cutedog good dog

اگر بین آکولادها علامت «,» یا بسط متغیر وجود نداشته باشد، بسط داده نخواهند شد:

# This {} isn't special
> echo foo-{}
foo-{}
# This passes "HEAD@{2}" to git
> git reset --hard HEAD@{2}
> echo {{a,b}}
{a} {b} # because the inner brace pair is expanded, but the outer isn't.

اگر پس از بسط، چیزی میان آکولادها باقی نماند، آن آرگومان به کلی حذف می‌شود (بخش ترکیب فهرست‌ها را ببینید):

> echo foo-{$undefinedvar}
# Output is an empty line, like a bare `echo`.

اگر بین یک آکولاد و یک کاما، یا بین دو کاما چیزی وجود نداشته باشد، به عنوان یک عنصر خالی تفسیر می‌شود:

> echo {,,/usr}/bin
/bin /bin /usr/bin

برای استفاده از «,» به عنوان یک عنصر عادی، آن را نقل‌قول کنید یا با نویسه گریز بنویسید.

نخستین کاراکتر از توکن یک دستور هرگز به عنوان بسط آکولاد تفسیر نمی‌شود، زیرا نشانه شروع یک دستور مرکب (compound statement) است:

> {echo hello, && echo world}
hello,
world

ترکیب فهرست‌ها (Combining lists)

پوسته فیش فهرست‌ها را همانند بسط‌های آکولاد بسط می‌دهد:

>_ set -l foo x y z
>_ echo 1$foo
# Any element of $foo is combined with the "1":
1x 1y 1z
>_ echo {good,bad}" apples"
# Any element of the {} is combined with the " apples":
good apples bad apples
# Or we can mix the two:
>_ echo {good,bad}" "$foo
good x bad x good y bad y good z bad z

هر رشته‌ای که به یک فهرست متصل شود، به تک‌تک عناصر آن الحاق خواهد شد.

دو فهرست در تمامی ترکیبات ممکن بسط می‌یابند - هر عنصر از فهرست اول با هر عنصر از فهرست دوم:

>_ set -l a x y z; set -l b 1 2 3
>_ echo $a$b # same as {x,y,z}{1,2,3}
x1 y1 z1 x2 y2 z2 x3 y3 z3

پیامد این رفتار آن است که اگر یک فهرست عنصری نداشته باشد، رشته با صفر عنصر ترکیب می‌شود و در نتیجه کل توکن حذف خواهد شد!

>_ set -l c # <- this list is empty!
>_ echo {$c}word
# Output is an empty line - the "word" part is gone

این ویژگی می‌تواند بسیار مفید باشد. برای مثال اگر می‌خواهید تمام فایل‌های موجود در تمامی دایرکتوری‌های متغیر PATH را بررسی کنید:

for file in $PATH/*

از آنجا که PATH یک فهرست است، این عبارت به تمام فایل‌های درون تمام دایرکتوری‌های آن بسط می‌یابد. و اگر هیچ دایرکتوری در PATH نباشد، پاسخ درست این است که به هیچ فایلی بسط پیدا نکند.

گاهی ممکن است این رفتار ناخواسته باشد، به ویژه ناپدید شدن توکن‌ها پس از بسط. در چنین مواردی باید متغیرها را درون نقل‌قول دوتایی قرار دهید - مانند echo "$c"word.

این وضعیت پس از جایگزینی دستور نیز اتفاق می‌افتد. برای جلوگیری از ناپدید شدن توکن‌ها در آنجا، کاری کنید که دستور درونی یک خط جدید انتهایی برگرداند یا آن را درون نقل‌قول دوتایی بگذارید:

>_ set b 1 2 3
>_ echo (echo x)$b
x1 x2 x3
>_ echo (printf '%s' '')banana
# the printf prints nothing, so this is nothing times "banana",
# which is nothing.
>_ echo (printf '%s\n' '')banana
# the printf prints a newline,
# so the command substitution expands to an empty string,
# so this is `''banana`
banana
>_ echo "$(printf '%s' '')"banana
# quotes mean this is one argument, the banana stays

برش‌ها (Slices)

گاهی لازم است تنها به برخی از عناصر یک فهرست دسترسی داشته باشید (تمامی متغیرهای فیش فهرست هستند)، یا برخی از خطوط خروجی یک جایگزینی دستور را دریافت کنید. در فیش هر دو کار با نوشتن مجموعه‌ای از نمایه‌ها (اندیس‌ها) درون براکت امکان‌پذیر است، مانند:

# Make $var a list of four elements
set var one two three four
# Print the second:
echo $var[2]
# prints "two"
# or print the first three:
echo $var[1..3]
# prints "one two three"

درون براکت‌های نمایه، فیش بازه‌هایی به شکل a..b را درک می‌کند (که در آن «a» و «b» نمایه هستند). آن‌ها به توالی نمایه‌ها از a تا b بسط می‌یابند (یعنی a a+1 a+2 ... b)؛ اگر b بزرگتر باشد صعودی و اگر a بزرگتر باشد نزولی خواهند بود. نمایه‌های منفی نیز قابل استفاده‌اند - این نمایه‌ها از انتهای فهرست محاسبه می‌شوند، بنابراین -1 آخرین عنصر است و -2 عنصر یکی مانده به آخر. اگر نمایه‌ای وجود نداشته باشد، بازه تا نزدیک‌ترین نمایه ممکن تنظیم و محدود (clamp) می‌شود.

اگر یک فهرست ۵ عنصر داشته باشد، نمایه‌ها از ۱ تا ۵ هستند؛ بنابراین بازه 2..16 تنها از عنصر ۲ تا ۵ پیش می‌رود.

اگر انتهای بازه منفی باشد، مسیر بازه همیشه صعودی است؛ بنابراین 2..-2 از عنصر ۲ تا ۴ می‌رود، و 2..-16 به هیچ کجا نمی‌رود چون هیچ راهی برای رفتن صعودی از عنصر دوم به عنصری که وجود ندارد وجود ندارد. اگر ابتدای بازه منفی باشد، مسیر همیشه نزولی است؛ بنابراین -2..1 از عنصر ۴ تا ۱ می‌رود، و -16..2 به هیچ کجا نمی‌رود چون راهی برای رفتن نزولی از عنصری ناموجود به عنصر دوم وجود ندارد.

نبود نمایه آغازین در یک بازه به طور پیش‌فرض برابر با ۱ در نظر گرفته می‌شود. این حالت در صورتی مجاز است که بازه، نخستین عبارت نمایه‌ای در توالی باشد. به همین ترتیب، نبود نمایه پایانی به طور پیش‌فرض برابر با -1 در نظر گرفته می‌شود که برای آخرین نمایه در توالی مجاز است.

استفاده از چندین بازه نیز امکان‌پذیر است که با فاصله از هم جدا می‌شوند.

چند مثال:

echo (seq 10)[1 2 3]
# Prints: 1 2 3
# Limit the command substitution output
echo (seq 10)[2..5]
# Uses elements from 2 to 5
# Output is: 2 3 4 5
echo (seq 10)[7..]
# Prints: 7 8 9 10
# Use overlapping ranges:
echo (seq 10)[2..5 1..3]
# Takes elements from 2 to 5 and then elements from 1 to 3
# Output is: 2 3 4 5 1 2 3
# Reverse output
echo (seq 10)[-1..1]
# Uses elements from the last output line to
# the first one in reverse direction
# Output is: 10 9 8 7 6 5 4 3 2 1
# The command substitution has only one line,
# so these will result in empty output:
echo (echo one)[2..-1]
echo (echo one)[-3..1]

همین قاعده هنگام تنظیم یا بسط متغیرها نیز کار می‌کند:

# Reverse path variable
set PATH $PATH[-1..1]
# or
set PATH[-1..1] $PATH
# Use only n last items of the PATH
set n -3
echo $PATH[$n..-1]

می‌توان از متغیرها به عنوان نمایه برای بسط متغیرها استفاده کرد، مانند:

set index 2
set letters a b c d
echo $letters[$index] # returns 'b'

با این حال، استفاده از متغیرها به عنوان نمایه برای جایگزینی دستور در حال حاضر پشتیبانی نمی‌شود:

echo (seq 5)[$index] # This won't work
set sequence (seq 5) # It needs to be written on two lines like this.
echo $sequence[$index] # returns '2'

هنگام استفاده از بسط غیرمستقیم متغیر با چندین علامت $ ($$name)، باید تمام نمایه‌ها را تا رسیدن به متغیری که می‌خواهید برش بزنید مشخص کنید:

> set -l list 1 2 3 4 5
> set -l name list
> echo $$name[1]
1 2 3 4 5
> echo $$name[1..-1][1..3] # or $$name[1][1..3], since $name only has one element.
1 2 3

بسط دایرکتوری خانگی (Home directory expansion)

نویسه مدک ~ در ابتدای یک پارامتر، چنانچه با یک نام کاربری دنبال شود، به دایرکتوری خانگی کاربر مشخص‌شده بسط می‌یابد. علامت ~ به تنهایی یا دنبال‌شده با یک اسلش، به دایرکتوری خانگی مالک فرآیند جاری بسط داده می‌شود:

ls ~/Music # lists my music directory
echo ~root # prints root's home directory, probably "/root"

ترکیب بسط‌های گوناگون (Combining different expansions)

تمام بسط‌های بالا را می‌توان با یکدیگر ترکیب کرد. اگر چند بسط منجر به بیش از یک پارامتر شوند، تمام ترکیب‌های ممکن ساخته خواهند شد.

هنگام ترکیب چند بسط پارامتر، بسط‌ها با این ترتیب اولویت انجام می‌شوند:

بسط‌ها از راست به چپ انجام می‌شوند؛ بسط‌های تودرتوی براکت و جایگزینی‌های دستور از درون به بیرون اعمال می‌گردند.

مثال:

اگر دایرکتوری جاری حاوی فایل‌های «foo» و «bar» باشد، دستور echo a(ls){1,2,3} خروجی abar1 abar2 abar3 afoo1 afoo2 afoo3 را تولید خواهد کرد.

دامنه متغیرها (Variable Scope)

تمامی متغیرها در فیش دارای یک دامنه (scope) هستند. برای نمونه می‌توانند سراسری (global) یا برای یک تابع یا بلوک، محلی (local) باشند:

# This variable is global, we can use it everywhere.
set --global name Patrick
# This variable is local, it will not be visible in a function we call from here.
set --local place "at the Krusty Krab"
function local
    # This can find $name, but not $place
    echo Hello this is $name $place
    # This variable is local, it will not be available
    # outside of this function
    set --local instrument mayonnaise
    echo My favorite instrument is $instrument
    # This creates a local $name, and won't touch the global one
    set --local name Spongebob
    echo My best friend is $name
end
local
# Will print:
# Hello this is Patrick
# My favorite instrument is mayonnaise
# My best friend is Spongebob
echo $name, I am $place and my instrument is $instrument
# Will print:
# Patrick, I am at the Krusty Krab and my instrument is

در فیش چهار نوع دامنه برای متغیرها وجود دارد: متغیرهای جهانی (universal)، سراسری (global)، تابعی (function) و محلی (local).

متغیرها را می‌توان با سوییچ‌های -U یا --universal صراحتاً جهانی، با -g یا --global سراسری، با -f یا --function با دامنه تابع، و با -l یا --local برای بلوک جاری محلی تعریف کرد. قواعد تعیین دامنه هنگام ایجاد یا به‌روزرسانی یک متغیر به این صورت است:

می‌تواند چندین متغیر با یک نام اما در دامنه‌های متفاوت وجود داشته باشد. زمانی که از یک متغیر استفاده می‌کنید، متغیر با کوچک‌ترین دامنه در میان متغیرهای هم‌نام انتخاب خواهد شد. اگر یک متغیر محلی وجود داشته باشد، به جای متغیر سراسری یا جهانی هم‌نام خود به کار می‌رود.

مثال:

کاربردهای گوناگونی برای دامنه‌های مختلف وجود دارد.

معمولاً درون توابع باید از دامنه محلی استفاده کنید:

function something
    set -l file /path/to/my/file
    if not test -e "$file"
        set file /path/to/my/otherfile
    end
end
# or
function something
    if test -e /path/to/my/file
        set -f file /path/to/my/file
    else
        set -f file /path/to/my/otherfile
    end
end

اگر می‌خواهید مقداری را در config.fish تنظیم کنید، یا چیزی را درون یک تابع مقداردهی کنید تا برای بقیه مدت نشست در دسترس بماند، دامنه سراسری گزینه مناسبی است:

# Don't shorten the working directory in the prompt
set -g fish_prompt_pwd_dir_length 0
# Set my preferred cursor style:
function setcursors
   set -g fish_cursor_default block
   set -g fish_cursor_insert line
   set -g fish_cursor_visual underscore
end
# Set my language
set -gx LANG de_DE.UTF-8

در اینجا مقایسه‌ای بین متغیرهای محلی و متغیرهای با دامنه تابع آورده شده است:

function test-scopes
    begin
        # This is a nice local scope where all variables will die
        set -l pirate 'There be treasure in them thar hills'
        set -f captain Space, the final frontier
        # If no variable of that name was defined, it is function-local.
        set gnu "In the beginning there was nothing, which exploded"
    end
    # This will not output anything, since the pirate was local
    echo $pirate
    # This will output the good Captain's speech
    # since $captain had function-scope.
    echo $captain
    # This will output Sir Terry's wisdom.
    echo $gnu
end

هنگامی که یک تابع، تابع دیگری را فراخوانی می‌کند، متغیرهای محلی تابع اول برای دومی قابل مشاهده نیستند:

function shiver
    set phrase 'Shiver me timbers'
end
function avast
    set --local phrase 'Avast, mateys'
    # Calling the shiver function here can not
    # change any variables in the local scope
    # so phrase remains as we set it here.
    shiver
    echo $phrase
end
avast
# Outputs "Avast, mateys"

هنگام تردید، از متغیرهای با دامنه تابع استفاده کنید. هر گاه نیاز دارید متغیر در همه‌جا قابل دسترسی باشد، آن را سراسری کنید. هنگامی که می‌خواهید پیکربندی را به طور پایدار ذخیره نمایید، آن را جهانی سازید. و زمانی که می‌خواهید از متغیری فقط درون یک بلوک کوتاه بهره ببرید، آن را محلی تعریف کنید.

بازنویسی متغیرها برای یک دستور منفرد (Overriding variables for a single command)

اگر مایلید متغیری را صرفاً برای اجرای یک دستور منفرد بازنویسی (override) کنید، می‌توانید از عبارات «var=val» پیش از نام دستور استفاده نمایید:

# Call git status on another directory
# (can also be done via `git -C somerepo status`)
GIT_DIR=somerepo git status

برخلاف برخی پوسته‌های دیگر، فیش ابتدا متغیر را تنظیم کرده و سپس سایر بسط‌های خط فرمان را انجام می‌دهد؛ بنابراین:

set foo banana
foo=gagaga echo $foo
# prints gagaga, while in other shells it might print "banana"

امکان تعریف چندین عنصر از طریق بسط آکولاد نیز فراهم است:

# Call bash with a reasonable default path.
PATH={/usr,}/{s,}bin bash

یا از طریق یک الگوی عام (glob):

# Run vlc on all mp3 files in the current directory
# If no file exists it will still be run with no arguments
mp3s=*.mp3 vlc $mp3s

برخلاف پوسته‌های دیگر، این شیوه مانع جستجوی دستورات (نام‌های مستعار یا مشابه آن) نمی‌شود. فراخوانی یک دستور پس از تنظیم متغیر بازنویسی، دقیقاً منجر به اجرای همان دستور خواهد شد.

این نحو از نسخه ۳.۱ فیش پشتیبانی می‌شود.

متغیرهای سراسری جهانی (Universal Variables)

متغیرهای جهانی متغیرهایی هستند که میان تمامی نشست‌های فیش کاربر بر روی رایانه به اشتراک گذاشته می‌شوند. تمامی تغییرات در متغیرهای جهانی پایدار بوده و بی‌درنگ در تمامی نشست‌های فیش منتشر می‌شوند.

متغیرهای جهانی در فایل .config/fish/fish_variables ذخیره می‌گردند. این فایل را مستقیماً ویرایش نکنید، زیرا ممکن است تغییرات شما بازنویسی شود. در عوض، متغیرها را از طریق اسکریپت‌های فیش یا با استفاده تعاملی از فیش ویرایش نمایید.

از افزودن مقدار به متغیرهای جهانی در فایل config.fish خودداری کنید، چرا که در این صورت با باز شدن هر نمونه پوسته جدید، این متغیرها طولانی‌تر خواهند شد. به جای آن، یک بار آن‌ها را در خط فرمان تنظیم کنید.

صادر کردن متغیرها (Exporting variables)

متغیرها در فیش می‌توانند صادر (export) شوند تا توسط هر دستوری که توسط فیش راه‌اندازی می‌شود به ارث برسند. به طور خاص، این امر برای متغیرهایی که جهت پیکربندی دستورات خارجی استفاده می‌شوند (مانند PAGER یا GOPATH) و همچنین متغیرهایی که حاوی تنظیمات عمومی سیستم هستند (مانند PATH یا LANGUAGE) ضروری است. اگر یک دستور خارجی نیاز دارد از یک متغیر باخبر باشد، آن متغیر باید صادر شود. متغیرهای صادرشده اغلب «متغیرهای محیطی» نیز نامیده می‌شوند.

این اصل برای خود فیش نیز صادق است - هنگامی که راه‌اندازی می‌شود، متغیرهای محیطی را از والد خود (معمولاً ترمینال) دریافت می‌کند. این متغیرها معمولاً شامل تنظیمات سیستمی مانند PATH و متغیرهای محلی‌سازی (locale) هستند.

متغیرها را می‌توان با سوییچ -x یا --export صراحتاً صادر کرد، یا با سوییچ -u یا --unexport از حالت صادرشده خارج ساخت. قواعد صادر کردن هنگام تنظیم متغیر شبیه به قواعد دامنه متغیرهاست - هنگامی که گزینه‌ای ارسال شود اعمال می‌گردد، در غیر این صورت وضعیت فعلی متغیر استفاده می‌شود. اگر گزینه‌ای مشخص نشود و متغیر از قبل وجود نداشته باشد، صادر نخواهد شد.

بر اساس یک قرارداد نام‌گذاری، متغیرهای صادرشده با حروف بزرگ و متغیرهای صادرنشده با حروف کوچک نوشته می‌شوند.

برای نمونه:

set -gx ANDROID_HOME ~/.android # /opt/android-sdk
set -gx CDPATH . ~ (test -e ~/Videos; and echo ~/Videos)
set -gx EDITOR emacs -nw
set -gx GOPATH ~/dev/go
set -gx GTK2_RC_FILES "$XDG_CONFIG_HOME/gtk-2.0/gtkrc"
set -gx LESSHISTFILE "-"

نکته: صادر کردن (exporting) یک دامنه نیست، بلکه یک وضعیت تکمیلی است. معمولاً منطقی است که متغیرهای صادرشده را سراسری (global) نیز تعریف کنید، اما متغیرهای صادرشده محلی نیز می‌توانند کاربردی باشند اگر به چیزی دقیق‌تر از بازنویسی‌های موقت نیاز دارید. این متغیرها در هنگام ارسال به توابع کپی می‌شوند تا تابع نتواند آن‌ها را در بیرون تغییر دهد، و همچنان در دسترس دستورات خارجی نیز خواهند بود. متغیرهای سراسری چه صادر شده باشند و چه نشده باشند، برای توابع قابل دسترسی هستند.

فهرست‌ها (Lists)

پوسته فیش می‌تواند یک فهرست (یا در صورت تمایل یک «آرایه») از چندین رشته را درون یک متغیر ذخیره کند:

> set mylist first second third
> printf '%s\n' $mylist # prints each element on its own line
first
second
third

برای دسترسی به یک عنصر از فهرست، از نمایه (اندیس) آن عنصر درون براکت استفاده کنید، مانند:

echo $PATH[3]

نمایه‌های فهرست در فیش از ۱ آغاز می‌شوند، نه از ۰ مانند سایر زبان‌ها. علت این است که نیاز به کسر عدد ۱ را کاهش می‌دهد و بسیاری از ابزارهای رایج یونیکس مانند seq با این شیوه بهتر کار می‌کنند (seq 5 اعداد ۱ تا ۵ را چاپ می‌کند، نه ۰ تا ۵). نمایه نامعتبر بدون هشدار نادیده گرفته شده و مقداری برنمی‌گرداند (حتی رشته خالی برنمی‌گرداند، یعنی هیچ آرگومانی ارسال نمی‌شود).

اگر از هیچ براکتی استفاده نکنید، تمامی عناصر فهرست به صورت آیتم‌های مجزا به دستور ارسال خواهند شد. این یعنی می‌توانید با حلقه for روی یک فهرست پیمایش کنید:

for i in $PATH
    echo $i is in the path
end

این دستور تمام دایرکتوری‌های موجود در PATH را به صورت جداگانه پیمایش کرده و برای هر کدام خطی چاپ می‌کند که نشان می‌دهد در مسیر قرار دارد.

برای ایجاد متغیر smurf که حاوی آیتم‌های blue و small باشد، بنویسید:

set smurf blue small

همچنین امکان مقداردهی یا حذف تک‌تک عناصر یک فهرست وجود دارد:

# Set smurf to be a list with the elements 'blue' and 'small'
set smurf blue small
# Change the second element of smurf to 'evil'
set smurf[2] evil
# Erase the first element
set -e smurf[1]
# Output 'evil'
echo $smurf

اگر هنگام بسط یا مقداردهی به یک متغیر فهرستی، نمایه منفی مشخص کنید، نمایه از انتهای فهرست محاسبه می‌شود. برای مثال، نمایه -1 آخرین عنصر فهرست است:

> set fruit apple orange banana
> echo $fruit[-1]
banana
> echo $fruit[-2..-1]
orange
banana
> echo $fruit[-1..1] # reverses the list
banana
orange
apple

همان‌طور که مشاهده می‌کنید، می‌توانید از بازه‌ای از نمایه‌ها استفاده کنید؛ برای جزئیات به بخش برش‌ها (slices) مراجعه نمایید.

تمام فهرست‌ها تک‌بعدی هستند و نمی‌توانند حاوی فهرست‌های دیگر باشند، هرچند شبیه‌سازی فهرست‌های تودرتو با استفاده از ارجاع‌زدایی امکان‌پذیر است - بخش بسط متغیرها را ببینید.

هنگامی که یک فهرست به عنوان متغیر محیطی صادر می‌شود، بسته به اینکه متغیر مسیر (path variable) باشد یا خیر، با فاصله یا با دونقطه تفکیک می‌گردد:

> set -x smurf blue small
> set -x smurf_PATH forest mushroom
> env | grep smurf
smurf=blue small
smurf_PATH=forest:mushroom

فیش به طور خودکار از تمامی متغیرهای محیطی که نامشان به PATH ختم می‌شود (مانند PATH، CDPATH یا MANPATH)، از طریق تفکیک بر اساس دونقطه، فهرست ایجاد می‌کند. متغیرهای دیگر به طور خودکار تفکیک نمی‌شوند.

فهرست‌ها را می‌توان با دستورات count <> یا contains <> بررسی و بازرسی کرد:

> count $smurf
2
> contains blue $smurf
# blue was found, so it exits with status 0
# (without printing anything)
> echo $status
0
> contains -i blue $smurf
1

ویژگی عالی فهرست‌ها این است که به دستورات به صورت هر عنصر در قالب یک آرگومان مستقل منتقل می‌شوند؛ بنابراین به محض مقداردهی فهرست، می‌توانید آن را ارسال کنید:

set -l grep_args -r "my string"
grep $grep_args . # will run the same as `grep -r "my string"` .

برخلاف پوسته‌های دیگر، فیش «تفکیک کلمات» (word splitting) را انجام نمی‌دهد - عناصر درون فهرست همان‌گونه که هستند باقی می‌مانند، حتی اگر شامل فاصله یا تب باشند.

مدیریت آرگومان‌ها (Argument Handling)

یک فهرست مهم متغیر $argv است که شامل آرگومان‌های ارسالی به یک تابع یا اسکریپت می‌باشد. برای نمونه:

function myfunction
    echo $argv[1]
    echo $argv[3]
end

این تابع هر آرگومانی را که دریافت کند می‌گیرد و آرگومان‌های اول و سوم را چاپ می‌کند:

> myfunction first second third
first
third
> myfunction apple cucumber banana
apple
banana

این موضوع آرگومان‌های مکانی (positional arguments) را پوشش می‌دهد، اما ابزارهای خط فرمان معمولاً گزینه‌ها و فلگ‌های گوناگونی دریافت می‌کنند و $argv آن‌ها را درهم‌آمیخته با آرگومان‌های مکانی نگه می‌دارد. روش معمول مدیریت آرگومان در یونیکس از گزینه‌های کوتاه (-h، و همچنین گروه‌بندی‌شده مانند ls -lah)، گزینه‌های بلند (--help) و امکان آرگومان گرفتن این گزینه‌ها (--color=auto یا --position anywhere یا complete -C"git ") و همچنین جداکننده -- برای مشخص کردن پایان گزینه‌ها پشتیبانی می‌کند. مدیریت دستی تمام این موارد دشوار و مستعد خطاست.

یک روش قوی‌تر برای مدیریت گزینه‌ها دستور توکار argparse <> است که گزینه‌های تعریف‌شده را بررسی کرده و درون متغیرهای مختلف قرار می‌دهد، به طوری که تنها آرگومان‌های مکانی در $argv باقی می‌مانند. در اینجا یک مثال ساده آورده شده است:

function mybetterfunction
    # We tell argparse about -h/--help and -s/--second
    # - these are short and long forms of the same option.
    # The "--" here is mandatory,
    # it tells it from where to read the arguments.
    argparse h/help s/second -- $argv
    # exit if argparse failed because
    # it found an option it didn't recognize
    # - it will print an error
    or return
    # If -h or --help is given, we print a little help text and return
    if set -ql _flag_help
        echo "mybetterfunction [-h|--help] [-s|--second] [ARGUMENT ...]"
        return 0
    end
    # If -s or --second is given, we print the second argument,
    # not the first and third.
    # (this is also available as _flag_s because of the short version)
    if set -ql _flag_second
        echo $argv[2]
    else
        echo $argv[1]
        echo $argv[3]
    end
end

گزینه‌ها از $argv حذف خواهند شد، بنابراین اکنون $argv[2] دومین آرگومان مکانی است:

> mybetterfunction first -s second third
second

برای اطلاعات بیشتر درباره argparse، از جمله نحوه مدیریت آرگومان‌های گزینه‌ها، مستندات argparse <> را ببینید.

متغیرهای PATH (PATH variables)

متغیرهای مسیر (Path variables) نوع خاصی از متغیرها هستند که برای پشتیبانی از فهرست‌های مسیر تفکیک‌شده با دونقطه به کار می‌روند؛ از جمله PATH، CDPATH، MANPATH، PYTHONPATH، LANGUAGE (برای بومی‌سازی <>) و غیره. تمام متغیرهایی که نامشان به «PATH» ختم می‌شود (حساس به بزرگی و کوچکی حروف)، به صورت پیش‌فرض متغیر مسیر می‌شوند.

متغیرهای PATH مانند فهرست‌های عادی رفتار می‌کنند، با این تفاوت که به طور ضمنی بر اساس دونقطه به هم پیوند خورده یا تفکیک می‌شوند.

set MYPATH 1 2 3
echo "$MYPATH"
# 1:2:3
set MYPATH "$MYPATH:4:5"
echo $MYPATH
# 1 2 3 4 5
echo "$MYPATH"
# 1:2:3:4:5

متغیرهای مسیر هنگام صادر شدن نیز در قالب دونقطه صادر می‌شوند؛ بنابراین با اجرای set -x MYPATH 1 2 3، دستورات خارجی آن را به صورت 1:2:3 خواهند دید.

> set -gx MYPATH /bin /usr/bin /sbin
> env | grep MYPATH
MYPATH=/bin:/usr/bin:/sbin

این امر برای سازگاری با سایر ابزارهاست. یونیکس متغیرهایی با چندین عنصر ندارد؛ نزدیک‌ترین چیز به آن فهرست‌های تفکیک‌شده با دونقطه مانند PATH است. به دلایل واضح، این یعنی هیچ عنصری نمی‌تواند شامل نویسه : باشد.

متغیرها را می‌توان از طریق گزینه‌های --path و --unpath در دستور set به عنوان متغیر مسیر نشانه‌گذاری کرده یا از این حالت خارج ساخت.

متغیرهای ویژه (Special variables)

می‌توانید با تغییر مقادیر برخی متغیرها، تنظیمات فیش را دگرگون سازید.

فیش همچنین اطلاعات تکمیلی را از طریق مقادیر برخی متغیرهای محیطی فراهم می‌کند. بیشتر این متغیرها فقط‌خواندنی هستند و مقدار آن‌ها را نمی‌توان با set تغییر داد.

به عنوان یک قرارداد، معمولاً برای متغیرهای صادرشده از حروف بزرگ و برای متغیرهای صادرنشده از حروف کوچک استفاده می‌شود (CMD_DURATION به دلایل تاریخی یک استثنا است). این قاعده توسط فیش تحمیل نمی‌شود، اما تمایز گذاشتن میان متغیرهای صادرشده و صادرنشده از طریق حروف‌بندی یک شیوه کدنویسی پسندیده است.

فیش همچنین از برخی متغیرها به صورت داخلی استفاده می‌کند که نام آن‌ها معمولاً با __fish آغاز می‌شود. این متغیرها داخلی هستند و معمولاً نباید مستقیماً تغییر داده شوند.

متغیر وضعیت (The status variable)

هر گاه فرآیندی به پایان می‌رسد، یک وضعیت خروج (exit status) به برنامه‌ای که آن را اجرا کرده (معمولاً پوسته) بازگردانده می‌شود. این وضعیت خروج یک عدد صحیح است که به برنامه فراخواننده می‌گوید اجرای دستور چگونه پیش رفته است. به طور کلی، وضعیت خروج صفر یعنی دستور بدون مشکل اجرا شده است، اما وضعیت خروج غیرصفر به معنای بروز نوعی خطا یا مشکل است.

فیش وضعیت خروج آخرین فرآیند از آخرین کاری را که خاتمه یافته است در متغیر status ذخیره می‌کند.

اگر فیش هنگام اجرای یک دستور با مشکلی روبرو شود، متغیر وضعیت ممکن است روی مقداری خاص تنظیم گردد:

اگر فرآیندی با دریافت یک سیگنال پایان یابد، وضعیت خروج برابر با ۱۲۸ به علاوه شماره آن سیگنال خواهد بود.

وضعیت را می‌توان با کلیدواژه not <> (یا !) نفی کرد که در شرط‌ها بسیار کاربردی است. این عمل وضعیت 0 را به 1 و هر وضعیت غیرصفری را به 0 تبدیل می‌کند.

همچنین متغیر $pipestatus وجود دارد که فهرستی از تمامی مقادیر status فرآیندهای درون یک پایپ است. یک تفاوت این است که not <> بر روی $status اعمال می‌شود، اما روی $pipestatus اثر ندارد زیرا باعث از دست رفتن اطلاعات می‌گردد.

برای نمونه:

not cat file | grep -q fish
echo status is: $status pipestatus is $pipestatus

در اینجا $status نمایانگر وضعیت دستور grep است که در صورت یافتن مورد تطبیق 0 برمی‌گرداند، و با not نفی می‌شود (بنابراین در صورت یافتن 1 و در غیر این صورت 0 خواهد بود). متغیر $pipestatus وضعیت‌های دستور cat (که مثلاً در صورت نیافتن فایل مقداری غیرصفر برمی‌گرداند) و grep را بدون عمل نفی نشان می‌دهد.

بنابراین اگر هر دو دستور cat و grep موفق شوند، $status به دلیل وجود not برابر با 1 خواهد بود، در حالی که $pipestatus برابر با 0 و 0 خواهد شد.

این احتمال وجود دارد که دستور اول شکست بخورد در حالی که دستور دوم با موفقیت انجام شود. یک نمونه متداول زمانی است که برنامه دوم زودتر از موعد به کار خود پایان دهد.

برای مثال اگر خط لوله‌ای به این شکل داشته باشید:

cat file1 file2 | head -n 50

این دستور به cat می‌گوید دو فایل «file1» و «file2» را پشت سر هم چاپ کند، و دستور head تنها ۵۰ خط اول را نمایش می‌دهد. در این وضعیت ممکن است مکرراً چنین وضعیتی را مشاهده کنید:

> cat file1 file2 | head -n 50
# 50 lines of output
> echo $pipestatus
141 0

در اینجا مقدار «141» نشان می‌دهد که cat با سیگنال شماره ۱۳ (128 + 13 == 141) یعنی سیگنال SIGPIPE کشته شده است. همچنین می‌توانید از fish_kill_signal برای دیدن شماره سیگنال استفاده کنید. دلیل این رخداد این است که دستور هنوز در حال کار بود و سپس head لوله را بست؛ در نتیجه cat سیگنالی دریافت کرد که آن را نادیده نگرفت و به این ترتیب پایان یافت.

اینکه آیا cat در اینجا با یک SIGPIPE مواجه می‌شود یا خیر به طول فایل و حجم داده‌ای که در یک لحظه می‌نویسد بستگی دارد، بنابراین ممکن است بسته به پیاده‌سازی، متغیر pipestatus را به صورت «0 0» مشاهده کنید. این یک مسئله عمومی در یونیکس است و مختص فیش نیست. برخی از پوسته‌ها از قابلیتی به نام «pipefail» برخوردارند که در صورت شکست هر یک از فرآیندهای لوله کل آن را ناموفق اعلام می‌کنند، و این موضوع چالشی بزرگ برای آن ویژگی محسوب می‌شود.

متغیرهای محلی‌سازی (Locale Variables)

تنظیمات محلی‌سازی (locale) یک برنامه، مجموعه تنظیمات زبانی و منطقه‌ای آن است. در یونیکس، این موارد از چندین دسته‌بندی تشکیل شده‌اند. دسته‌بندی‌های مورد استفاده در فیش عبارتند از:

پروفایل کردن اسکریپت‌های فیش (Profiling fish scripts)

اگر به طور مشخص می‌خواهید مسائل مربوط به عملکرد و کارایی را اشکال‌زدایی کنید، fish را می‌توان با گزینه --profile /path/to/profile.log اجرا کرد تا اطلاعات پروفایل را در مسیر مشخص‌شده ذخیره کند. این گزارش پروفایل شامل تفکیک مدت زمانی است که هر گام در فرآیند اجرا طول کشیده است.

برای مثال:

> fish --profile /tmp/sleep.prof -ic 'sleep 3s'
> cat /tmp/sleep.prof
Time    Sum     Command
3003419 3003419 > sleep 3s

این دستور زمان لازم برای خود دستور را در ستون اول، زمان کل برای دستور و تمامی زیردستورات (مانند هر دستوری درون تابع یا جایگزینی‌های دستور) را در ستون دوم، و خود دستور را در ستون سوم، جداشده با تب، نشان می‌دهد.

زمان بر حسب میکروثانیه ارائه می‌شود.

برای دیدن کندترین دستورات در انتها، دستور sort -nk2 /path/to/logfile کاربردی است.

برای پروفایل زمان راه‌اندازی فیش، گزینه --profile-startup /path/to/logfile نیز وجود دارد.

برای اطلاعات بیشتر مستندات fish <> را ببینید.